Subject: PATCH: widget completion
From: Oliver Kiddle <[email-masked]>
To: Zsh workers <[email-masked]>
Date: Thu, 28 Jul 2016 00:27:34 +0200
List-Id: Zsh Workers List <zsh-workers.zsh.org>

We've got quite a few functions that need to complete zle widgets so it
seems to warrant factoring out into an _widgets function. This at least
encapsulates the matching control.

Like _parameters and _files, this takes a -g option to glob match
against the values in $widgets.

Oliver

diff --git a/Completion/Zsh/Command/_bindkey b/Completion/Zsh/Command/_bindkey
index 4c4aeda..81ae699 100644
--- a/Completion/Zsh/Command/_bindkey
+++ b/Completion/Zsh/Command/_bindkey
@@ -27,14 +27,11 @@ _arguments -C -s -S \
   '(-l -L -d -D -A -N -m -p -r *)-s[bind each in-string to each out-string]:*:key string' \
   '(-e -v -a -M -l -L -d -D -A -N -m -p)-R[interpret in-strings as ranges]' \
   '(-l -L -d -A -N -m -p -r -s):in-string' \
-  '(-l -L -d -A -N -m -p -r -s)*::widgets:->widget' && ret=0
+  '(-l -L -d -A -N -m -p -r -s)*::widgets:_widgets' && ret=0
 
 case $state in
   keymap)
-    _wanted -C -M keymaps expl keymap compadd -a keymaps && ret=0
-  ;;
-  widget)
-    _wanted widgets expl widget compadd -M 'r:|-=* r:|=*' -k widgets && ret=0
+    _wanted keymaps expl keymap compadd -a keymaps && ret=0
   ;;
 esac
 
diff --git a/Completion/Zsh/Command/_vared b/Completion/Zsh/Command/_vared
index 2bcc87b..aba6488 100644
--- a/Completion/Zsh/Command/_vared
+++ b/Completion/Zsh/Command/_vared
@@ -6,8 +6,8 @@ _arguments -s -A "-*" \
   "-c[create parameter or change type]" \
   '-p+[specify left prompt]:prompt' \
   '-r+[specify right prompt]:right prompt' \
-  '-i+[specify initialisation widget]:widget:compadd -M "r\:|-=* r\:|=*" -k widgets' \
-  '-f+[specify finish widget]:widget:compadd -M "r\:|-=* r\:|=*" -k widgets' \
+  '-i+[specify initialisation widget]:widget:_widgets' \
+  '-f+[specify finish widget]:widget:_widgets' \
   '-h[allow access to history]' \
   '-e[exit on EOF (^D)]' \
   '1:parameter spec:_vars'
diff --git a/Completion/Zsh/Command/_zle b/Completion/Zsh/Command/_zle
index 3ed3733..f189b8f 100644
--- a/Completion/Zsh/Command/_zle
+++ b/Completion/Zsh/Command/_zle
@@ -48,20 +48,20 @@ case "$state[1]" in
       '(-)*:widget arguments: ' && ret=0
     ;;
   (widget*)
-    _wanted -C "$context[1]" widgets expl "${state_descr[1]:-widget}" compadd -k widgets && ret=0
+    _wanted -C "$context[1]" widgets expl "${state_descr[1]:-widget}" _widgets && ret=0
     ;&
   (function)
     [[ $state[1] != *function ]] ||	# Handle fall-through
     _wanted -C "$context[1]" functions expl 'widget shell function' \
-      compadd -k functions && ret=0
+      compadd -M 'r:|-=* r:|=*' -k functions && ret=0
     ;;
   (comp-widget)
     _wanted -C "$context[1]" widgets expl 'completion widget' \
-      compadd -k "widgets[(R)(*:|)(.|)(${(j(|))compwids})(|:*)]" && ret=0
+      _widgets -g "(*:|)(.|)(${(j(|))compwids})(|:*)" && ret=0
     ;&
   (builtin-comp-widget)
     _wanted -C "$context[1]" widgets expl 'builtin completion widget' \
-      compadd -k "widgets[(I)(.|)(${(j(|))compwids})]" && ret=0
+      compadd -M 'r:|-=* r:|=*' -k "widgets[(I)(.|)(${(j(|))compwids})]" && ret=0
     ;;
   (redisplay)
     _arguments -s -S '!-R' \
diff --git a/Completion/Zsh/Function/_add-zle-hook-widget b/Completion/Zsh/Function/_add-zle-hook-widget
index da65dd6..93954a2 100644
--- a/Completion/Zsh/Function/_add-zle-hook-widget
+++ b/Completion/Zsh/Function/_add-zle-hook-widget
@@ -4,7 +4,7 @@ _add-zle-hook-widget_types() {
   local -a tmp
 
   autoload -U add-zle-hook-widget
-  add-zle-hook-widget -h > /dev/null # sets the zstyle
+  add-zle-hook-widget -h >&/dev/null # sets the zstyle
   zstyle -g tmp zle-hook types
 
   compadd "$@" -M 'L:|=zle-' -M 'r:|-=* r:|=*' -- zle-${^tmp}
@@ -16,8 +16,7 @@ _add-zle-hook-widget_widgets() {
     zstyle -g tmp $line[1] widgets
     _wanted widgets expl "installed hook" compadd -- ${tmp#<->:} && return 0
   else
-    local -a user_widgets=( ${(k)widgets[(R)user:*]} )
-    _wanted widgets expl widget compadd -M 'r:|-=* r:|=*' -a user_widgets && return 0
+    _wanted widgets expl widget _widgets -g 'user:*' && return 0
   fi
   return 1
 }
diff --git a/Completion/Zsh/Type/_widgets b/Completion/Zsh/Type/_widgets
new file mode 100644
index 0000000..fdab281
--- /dev/null
+++ b/Completion/Zsh/Type/_widgets
@@ -0,0 +1,9 @@
+#autoload
+
+local expl pattern
+
+pattern=( -g \* )
+zparseopts -D -K -E g:=pattern
+
+_description widgets expl widget
+compadd "$@" "$expl[@]" -M 'r:|-=* r:|=*' - "${(@k)widgets[(R)${pattern[2]}]}"