Subject: Re: [patch] _man: Support directories with suffixes
From: Daniel Shahaf <[email-masked]>
To: [email-masked]
Date: Sun, 31 Jul 2016 16:23:21 +0000
List-Id: Zsh Workers List <zsh-workers.zsh.org>

This hasn't been committed.

Matthew Martin wrote on Thu, May 19, 2016 at 00:07:25 -0500:
> I couldn't figure out what was the purpose for using $~sect, so I just
> dropped the tilde.

I found it:

       -S list, -s list, --sections=list
              List is a colon- or comma-separated list of `order specific'
              manual sections to search.  This option overrides the $MANSECT
              environment variable.  (The -s spelling is for compatibility
              with System V.)

That's on linux; the 'else if' branch just above the diff context
implements that syntax.

896f43c broke that syntax too: the new %% causes a pattern syntax
error.  Your patch doesn't fix this problem (since it keeps the %%).

I'm therefore attaching an alternative patch which I believe will fix
both that issue and the issue you originally saw:

> 896f43c broke completion for man 3p <tab> on OpenBSD because those man
> pages are in /usr/share/man/man3p.

Testing on various OSes would be appreciated.

Thanks,

Daniel

> 
> 
> diff --git a/Completion/Unix/Command/_man b/Completion/Unix/Command/_man
> index 0534db7..9aec833 100644
> --- a/Completion/Unix/Command/_man
> +++ b/Completion/Unix/Command/_man
> @@ -52,7 +52,7 @@ _man() {
>    fi
>  
>    if [[ $sect = (<->*|1M|l|n) || $sect = \(*\|*\) ]]; then
> -    dirs=( $^_manpath/(sman|man|cat)${~sect%%[^0-9]#}/ )
> +    dirs=( $^_manpath/(sman|man|cat)($sect|${sect%%[^0-9]#})/ )
>      awk="\$2 == \"$sect\" {print \$1}"
>    else
>      dirs=( $^_manpath/(sman|man|cat)*/ )
> 
>From 6d635d29d6378c4b320a5c1561f5a2d0630e1932 Mon Sep 17 00:00:00 2001
From: Daniel Shahaf <[email-masked]>
Date: Sun, 31 Jul 2016 12:36:55 +0000
Subject: [PATCH] _man: Followup to 37634: unbreak OpenBSD 'man 3p' and Linux
 $MANSECT.

The breakage was reported in 38516.
---
 Completion/Unix/Command/_man | 16 +++++++++++-----
 1 file changed, 11 insertions(+), 5 deletions(-)

diff --git a/Completion/Unix/Command/_man b/Completion/Unix/Command/_man
index 5ace087..0b427d2 100644
--- a/Completion/Unix/Command/_man
+++ b/Completion/Unix/Command/_man
@@ -44,15 +44,21 @@ _man() {
   if [[ $OSTYPE = solaris* ]]; then
     sect=${${words[(R)-s*]#-s}:-$words[$words[(i)-s]+1]}
   elif [[ -n ${sect:=$words[$words[(i)-S]+1]} || -n ${sect:=$MANSECT} ]]; then
-    if [[ $sect != ${sect::="${sect//:/|}"} ]]; then
-      sect="($sect)"
-    fi
+    sect="${sect//:/|}"
+    sect="${sect//,/|}"
   elif (( CURRENT > 2 )); then
     sect=$words[2]
   fi
 
-  if [[ $sect = (<->*|1M|l|n) || $sect = \(*\|*\) ]]; then
-    dirs=( $^_manpath/(sman|man|cat)${~sect%%[^0-9]#}/ )
+  if [[ $sect = (<->*|1M|l|n) || $sect = *\|* ]]; then
+    () {
+      local -a sects=( ${(s.|.)sect} )
+      if [[ $sect != (l|n) ]]; then
+        sects=( ${sects%%[^0-9]#} )
+      fi
+      dirs=( $^_manpath/(sman|man|cat)${^sects}*/ )
+    }
+    if [[ $sect == *\|* ]]; then sect="($sect)"; fi
     awk="\$2 == \"$sect\" {print \$1}"
   else
     dirs=( $^_manpath/(sman|man|cat)*/ )